用固定效应（FE）来估计面板数据模型是经济学和其它学科经验研究最常用的方法。固定效应估计量消除了个体层面的异质性。包括时间固定效应可以解释影响所有个体的长期宏观冲击。消除个体和时间固定效应会得到更加可信的政策分析结论，尤其是当干预在处理组群与时间上有异质性效应时（Wooldridge，2021）。

众所周知，固定效应估计量所使用的组内转换可以消除核心解释变量的许多变动，这会导致不精确的FE估计量。例如，我们发现了碳排放权交易对能源结构转型有特别重要的效应，但置信区间可能太宽，从而不显著。在这种情形下，人们也可以使用随机效应（RE）估计量——对异质性误差施加一下二阶矩假设得到的广义最小二乘估计量。RE估计量通常比FE更精确，但是，在解释变量与个体不可观测的异质性特征相关时，RE估计是非一致性的。那么，在FE和RE之间选择时，其实就是检验解释变量是否与不可观测的异质性特征相关。

Hausman（1978）检验是一种常用的方式。但是Wooldridge（2010，2019）指出，在序列相关和异方差稳健情形下，常常使用的是传统的、非稳健的Hausman检验。扩展Mundlak（1978）方法，Wooldridge（2019）提出了一种更加稳健的Hausman检验方法。Yang and Schmidt（2021）提出了一种基于回归的Hausman检验来比较Hausman-Taylor（1981）估计量和FE估计量。YS仍然假设时变解释变量与不可观测个体异质性特征不相关。

我们可以不用选择FE和RE估计量，从而得到更加精确的处理效应估计量。Papke and Wooldridge（2022）（“A Simple, Robust Test for Choosing the Level of Fixed Effects in Linear Panel Data Models”）提出了一种思路来recover固定效应消除的时变解释变量的变动：在更高层级上消除不可观测异质性特征足矣。例如，我们有企业层面的面板数据，真正的FE估计量消除了企业层面的时间平均值。但是如果我们认为企业属于行业层面，我们可以思考一下消除行业层面的异质性特征足以确保解释变量的外生性。或者在学校层面的面板数据中，消除学区层面的异质性特征足矣。这也就意味着，我们控制更高层级的固定效应即可。

当更高层级的组群数量较小时，仅仅包括组群虚拟变量，然后估计随机效应方程。人们可以使用Wooldridge（2019）提出的VAT版本Hausman检验，即解释变量的时间均值包含在POLS或者RE估计中。例如，我们有中国家庭追踪调查微观数据，包括30个内地省级地区的虚拟变量并不会带来什么新问题。

但是，当更高层级的组群数量很大时，我们就需要保持谨慎。例如，如果我们知道家庭追踪调查的每个家庭的县级代码，那么，我们国家有几千个区县。这个时候，我们更关心的问题是，我们要控制地区层面的固定效应，还是应该控制家庭层面的固定效应？

Papke and Wooldridge（2022）提出了一个易于实施的算法来检验固定效应的层级，即稳健地检验是控制更高层面的固定效应，还是个体层面的固定效应？

步骤：

• ① 构建解释变量在时间层面的个体均值，；
• ② 用组群g层面的固定效应估计下列方程：

• ③ 用组群g的固定效应估计

并用稳健Wald检验（聚类在个体层面或者组群层面）来检验

这有什么实践含义呢？

第一，我们知道，获得处理效应一致估计量最稳健的分析是控制个体层面的固定效应。因此，如果个体层面的固定效应估计量足够精确，人们完全可以不用Papke and Wooldridge（2022）的方法。PW的检验方法适用于个体层面的固定效应可能非常不精确（例如，置信区间很大，不显著），以至于我们得不到什么具体的结论。这个时候就可以使用PW的方法来考虑一下使用更高层级的固定效应是否足够。

第二，如果核心解释变量还包括一些复杂的函数形式，例如，二次项或交互项，亦或者与时间虚拟变量的交乘项，那么，时间层面的均值都会出现在中。如果核心解释变量是二值型政策变量，或者一个时间不变的变量与时变变量交乘。上述方法仍然适用。

例子

Papke(2005)用1995年美国密西根如何资助学校的政策（学校支出政策）对4年级数学成绩的影响。原文使用的是IV方法，PW（2022）关心的问题是用学区层面的固定效应，而不是学校层面的固定效应，是否能估计出学校支出的效应？

* 加载数据
use "/Users/xuwenli/Library/CloudStorage/OneDrive-个人/DSGE建模及软件编程/教学大纲与讲稿/应用计量经济学讲稿/应用计量经济学讲稿与code/fixed_effects_level/meap94_98.dta", clear

sum

其中，math4是结果变量（4年级学生获得满意成绩的比例）。

xtset schid year
tab year

数据集分布在1994-1998年间，是一个非平衡面板，在1994-1995年，许多学校都没有报告生均支出。解释变量是lavgrexp（当年和上一学年实际生均支出均值的对数）。这个数据缺失的原因可能与学校层面的异质性特征有关，或者与学区层面异质性特征有关。学校的资助是学区层面决定的，然后学区将资金分配给学校。可能所有的资金分配过程都不是随机的，且与学校的特征有关系。

有两个控制变量，lunch(有资格获得联邦免费午餐的学生比例)、lenrol（入学数量的对数）。回归方程包括所有的时间虚拟变量。

* 传统的TWFE with 学校固定效应：学校聚类和学区聚类
xtreg math4 lavgrexp lunch lenrol i.year, fe vce(cluster schid)
xtreg math4 lavgrexp lunch lenrol i.year, fe vce(cluster distid)

* 学区固定效应
xtset distid

xtreg math4 lavgrexp lunch lenrol i.year, fe vce(cluster distid)

从上面的结果可以看出，学校支出政策对学校数学成绩的影响，在控制学校固定效应后，系数为6.288，95%置信水平下显著。而控制了更高层级固定效应（学区固定效应）后，系数变为-0.615，且在95%置信水平下不显著。

在来看看lunch的系数，也就是学校学生贫困率的近似指标。在控制学区固定效应后，lunch的系数为-0.312，在95%的置信水平下显著，即学生贫困率提升10%，数学成绩会下降3.1%。但是，当控制学校固定效应后，lunch的系数下降到-0.022，且在95%的置信水平下不显著。学校固定效应和学区固定效应下的lunch系数差异意味着，lunch在学校层面的变动非常重要。

接下来，我们可以利用PW的方法检验学区固定效应和学校固定效应。即

• 首先，计算解释变量的时间均值；
• 然后，包含均值跑TWFE回归；
• 用Wald检验H0；

* lavgrexpb lunchb lenrolb为解释变量均值
xtset distid
xtreg math4 lavgrexp lunch lenrol i.year lavgrexpb lunchb lenrolb ///
	y95b y96b y97b y98b , fe vce(cluster distid)

* 检验H0
test lavgrexpb lunchb lenrolb y95b y96b y97b y98b

结果显示，学区固定效应的F统计量F=13.87，p值为0，因此，拒绝学区层面固定效应，学校层面的固定效应更好。

另一种检验固定效应层级的方法：

* 稳健Hausman检验
* Reproduce the clustered standard errors for the schid-level FE estimator:
xtset schid
qui xtreg math4 lunch lenrol i.year, fe
predict ydd, e
qui xtreg math4 lavgrexp lunch lenrol i.year, fe
scalar b_lavgrexp_schid = _b[lavgrexp]
predict uddh, e
qui xtreg lavgrexp lunch lenrol i.year, fe
predict wdd, e
gen wddsq = wdd^2
sum wddsq
scalar addh = r(mean)
gen rddh = wdd*uddh/addh
reg rddh, vce(cluster schid)
reg rddh, vce(cluster distid)
* Confirm estimate of b_lavgrexp using Frisch-Waugh:
reg ydd wdd, vce(cluster schid)
reg ydd wdd, vce(cluster distid) 

* Now with district-level FEs:

xtset distid
qui xtreg math4 lunch lenrol i.year, fe
predict yd, e
qui xtreg math4 lavgrexp lunch lenrol i.year, fe
scalar b_lavgrexp_distid = _b[lavgrexp]
predict udh, e
qui xtreg lavgrexp lunch lenrol i.year, fe
predict wd, e
gen wdsq = wd^2
sum wdsq
scalar adh = r(mean)
gen rdh = wd*udh/adh
reg rdh, vce(cluster schid)
reg rdh, vce(cluster distid)
* Confirm estimate of b_lavgrexp using Frisch-Waugh:
reg yd wd, vce(cluster schid)
reg yd wd, vce(cluster distid) 

* Now obtain standard error for the difference in estimators of b_lavgrexp:
gen eh = rddh - rdh
reg eh, vce(cluster schid)
scalar se_schid = _se[_cons]
reg eh, vce(cluster distid)
scalar se_distid = _se[_cons]

* Construct the robust Hausman statistic:
scalar t_schid = (b_lavgrexp_schid - b_lavgrexp_distid)/se_schid
di t_schid
di 2*(1 - normal(abs(t_schid)))
scalar t_distid = (b_lavgrexp_schid - b_lavgrexp_distid)/se_distid
di t_distid
di 2*(1 - normal(abs(t_distid)))

上述结果显示，tH统计量为2.68，p值为0.007。这意味着在95%置信水平下强烈拒绝学区固定效应。

在PW文章的例子后面，作者还根据所研究问题的经济制度讨论了如何考虑固定效应层面问题。我读完这篇文章后的第一感觉是，选择固定效应层级，仍然要结合所研究问题的经济制度背景来讨论，然后在结合PW提出的定量检验方法。